Archivio

Archivio per la categoria ‘Second Life’

Notecard configurazione LSL

12 gennaio 2009 9 commenti

Uno dei primi problemi che affronta uno scripter LSL non esperto (ma anche uno esperto!) è quello di creare un file di testo esterno allo script, dove salvare i valori iniziali di una variabile.

Questa operazione è estremamente utile per aumentare la modularità di uno script e per attuare delle modifiche senza dover modificare e ricompilare il codice.

In script aventi una complessità medio-alta, la tecnica di salvare informazioni in un file di testo esterno è estremamente diffusa.

Il presente articolo si prefigge l’obiettivo di semplificare e rendere automatica una operazione di questo tipo. Lo script prevede una fase di impostazione delle variabile ed una fase di validazione delle stesse.

Inizio con il postare il codice completo del template per poi discutere le parti essenziali con un esempio.

// ReadConfiguration
//
// Il seguente template viene usato per leggere un file di configurazione.
// Il file di configurazione può essere formattato nel seguente modo:
// <var>        Singola variabile
// <var>=<var>    Variabile <var> che deve essere inizializzata con il valore in <var>
// # line        Linea di commento
//
// @version 1.0
// @author MarcoDuff Palen (http://www.marcoduff.com/)

// Variabili
string configNotecard;
integer line;
key requestId;

// Legge i singoli comandi di configurazione.
//
// @param var    Nome della variabile letta (sempre totalmente maiuscola).
// @param val    Valore della variabile associata o una stringa vuota in caso di nessuna inizializzazione.
readConfig(string var, string val) {
}

// Valida la configurazione.
//
// @return    Restituisce TRUE se la configurazione è valida, FALSE altrimenti.
integer validateConfig() {
    return TRUE;
}

// Stato di inizializzazione.
default {
    state_entry() {
        configNotecard = llGetScriptName()+".config";
        line = 0;
        requestId = llGetNotecardLine(configNotecard,line);
    }

    state_exit() {
        line = -1;
        requestId = NULL_KEY;
    }

    dataserver(key request_id, string data) {
        if(requestId==request_id) {
            if(data!=EOF) {
                data = llStringTrim(data,STRING_TRIM);
                if(llSubStringIndex(data,"#")!=0&&llStringLength(data)>0) {
                    list dataList = llParseString2List(data,["="],[]);
                    string var = llToUpper(llStringTrim(llList2String(dataList,0),STRING_TRIM));
                    string val = "";
                    if(llGetListLength(dataList)==2) val = llStringTrim(llList2String(dataList,1),STRING_TRIM);
                    readConfig(var,val);
                }
                line++;
                requestId = llGetNotecardLine(configNotecard,line);
            }
            else {
                integer validate = validateConfig();
                if(validate == TRUE) state ConfigOkState;
                else state ConfigErrorState;
            }
        }
    }
}

// Stato se la configurazione è andata a buon fine.
state ConfigOkState {
    changed(integer change) {
        if(change & CHANGED_INVENTORY) llResetScript();
    }
}

// Stato se la configurazione è errata.
state ConfigErrorState {
    changed(integer change) {
        if(change & CHANGED_INVENTORY) llResetScript();
    }
}

Lo script non fa altro che cercare il file di testo nel contents dell’oggetto chiamato come lo script e con estenzione .config, leggere tutte le righe del file ignorando le linee vuote e le linee che iniziano con il carattere #, validare le variabili lette e portarsi nello stato ConfigOkState se tutto è andato a buon fine o nello stato ConfigErrorState in caso di errori.

Questo significa che lo stato di default della nostra applicazione diventa ConfigOkState. Le uniche righe di codice da modificare nel template sono, infatti, l’inserimeto delle variabili utili al problema, il contenuto delle due funzioni readConfig e validateConfig e gli stati ConfigOkState e ConfigErrorState.

Facciamo un esempio che spiega il funzionamento del template.

Supponiamo di voler creare un oggetto che visualizzi un testo sopra di esso. Il testo ed il colore dell’oggetto devono essere specificati in un file di testo esterno allo script. Il testo deve sempre specificato, mentre il colore, se non specificato, deve essere nero.

Il modo più semplice per lavorare con questo template è creare prima il file di testo di configurazione. Suppunendo di voler visualizzare il testo “Prova riuscita!!!” di colore blu, il file di testo risulta essere il seguente:

# Questa è una prova di configurazione dello script ReadConfiguration

# Text indica il testo da visualizzare
text = Prova riuscita!!!

# Color è opzionale, fai i tentativi commentando o impostando la variabile!
color = <0.0,0.0,1.0>

Notate il massiccio uso di commenti (righe che iniziano con il carattere #) che verranno ignorati, insieme alle righe vuote, dallo script.

Come possiamo notare dal file di testo, per soddisfare questo problema abbiamo sicuramente bisogno di due variabili: la prima di tipo string per salvare il testo da visualizzare, la seconda di tipo vector per il colore.

Questo significa che al template bisogna aggiungere in testa il seguente codice:

string text;
vector color;

l’impostazione di queste due variabili viene fatto all’interno della funzione readConfig. Questa funzione, infatti, riceve in input due variabili chiamate var e val che contengono rispettivamente la parte sinistra e quella destra rispetto al simbolo = di ogni riga letta nel file di configurazione (se non è presente il simbolo = allora viene valorizzata solo la variabile var). La variabile var ha la particolarità di essere sempre in maiuscolo, mentre la variabile val mantiene i caratteri originali.

Per fare un esempio, quando lo script leggerà la riga “text = Prova riuscita!!!” richiamerà la funzione readConfig passando per var il valore “TEXT” mentre per val il valore “Prova riuscita!!!”.

Detto questo, modifichiamo l’interno della funzione readConfig per impostare le nostre variabili text e color in questo modo:

readConfig(string var, string val) {
    if(var=="TEXT") text = val;
    else if(var=="COLOR") color = (vector)val;
    else llOwnerSay("[WARNING] Variabile "+var+" alla linea "+(string)(line+1)+" non prevista.");
}

in questo modo quando verranno letti i due valori dal file di testo, questi verranno opportunamente impostati nelle variabili. Notate che in questa particolare implementazione, se viene letto un comando non previsto viene dato un warning all’owner dello script che ha un utile feedback (pensate a quante volte avete perso tempo inutile per un semplice errore di battitura come scrivere “calor” invece di “color” o simili… mettere feedback di questo tipo è sempre molto utile e assolutamente consigliato). Notate anche come ho utilizzato la variabile line che indica la linea corrente di lettura del file (p.s.: ho dovuto incrementarla di 1 visto che la prima riga di un file di testo parte da 0!).

Se vogliamo inserire una validazione o vogliamo mettere dei valori di default per una variabile, dobbiamo modificare il contenuto della funzione validateConfig (se non vogliamo farlo, ci basta lasciare il return TRUE;). Nel nostro esempio dobbiamo controllare che il testo sia stato inserito, visto che lo consideriamo obbligatorio, mentre dobbiamo controllare che se il colore non è stato inserito dobbiamo impostarlo a Nero. La modifica da attuare è la seguente:

integer validateConfig() {
    if(color == ZERO_VECTOR) color = <0.0,0.0,0.0>;

    if(llStringLength(text)==0) llOwnerSay("[ERROR] Non hai impostato la variabile TEXT");
    else return TRUE;

    return FALSE;
}

se noto che la variabile color non è stata impostato, lo imposta io a nero. Se noto che la variabile text non è stata impostata stampo un messaggio di errore. Notare che la funzione restituisce TRUE esclusivamente nel caso in cui la variabile text viene impostata, in tutti gli altri casi restituisce FALSE. Il risultato della funzione TRUE o FALSE impone il passaggio di stato rispettivamente a ConfigOkState a ConfigErrorState.

A questo punto non ci resta che riempire lo stato ConfigOkState con il codice che avremmo scritto nello stato default di un normale script ma supponendo che le variabili a noi utili siano già state impostate, mentre lo stato ConfigErrorState con eventuali messaggi di errore. Ad esempio:

state ConfigOkState {
    state_entry() {
        llSetText(text,color,1.0);
    }

    changed(integer change) {
        if(change & CHANGED_INVENTORY) llResetScript();
    }
}

state ConfigErrorState {
    state_entry() {
        llOwnerSay("Errore di configurazione nel file "+configNotecard);
    }
    changed(integer change) {
        if(change & CHANGED_INVENTORY) llResetScript();
    }
}

Notate che tutti e due gli stati gestiscono l’evento changed in modo da captare eventuali modifiche del file di configurazione e resettarsi in automatico (ovviamente se non si vuole questa estenzione basta cancellare l’evento!).

Per chiarezza posto il codice completo dell’esempio:

// ReadConfiguration
//
// Il seguente template viene usato per leggere un file di configurazione.
// Il file di configurazione può essere formattato nel seguente modo:
// <var>        Singola variabile
// <var>=<val>    Variabile <var> che deve essere inizializzata con il valore in <val>
// # line        Linea di commento
//
// @version 1.0
// @author MarcoDuff Palen (http://www.marcoduff.com/)

// QUI INSERISCO LE VARIABILI DA RIEMPIRE TRAMITE IL FILE DI CONFIGURAZIONE
string text;
vector color;

// Variabili
string configNotecard;
integer line;
key requestId;

// Legge i singoli comandi di configurazione.
//
// @param var        Nome della variabile letta (sempre totalmente maiuscola).
// @param val        Valore della variabile associata o una stringa vuota in caso di nessuna inizializzazione.
readConfig(string var, string val) {
    // QUI INSERISCO I SETTAGGI DELLE VARIABILI
    llOwnerSay("[INFO] Reading "+var+" = "+val+" on line "+(string)(line+1));
    if(var=="TEXT") text = val;
    else if(var=="COLOR") color = (vector)val;
    else llOwnerSay("[WARNING] Variabile "+var+" alla linea "+(string)(line+1)+" non prevista.");
}

// Valida la configurazione.
//
// @return            Restituisce TRUE se la configurazione è valida, FALSE altrimenti.
integer validateConfig() {
    // QUI INSERISCO L'EVENTUALE VALIDAZIONE DELLE VARIABILI

    // Il colore non è una variabile richiesta, se non viene impostata la imposto a nero
    if(color == ZERO_VECTOR) color = <0.0,0.0,0.0>;

    // Il testo è una variabile fondamentale, mando un messaggio di errore
    if(llStringLength(text)==0) llOwnerSay("Non hai impostato la variabile TEXT");
    else return TRUE;

    return FALSE;
}

// Funzione per la visualizzazione dell'output.
//
// @param message    Messaggio da visualizzare.
// @param color        Colore di visualizzazione.
showOutput(string message, vector color) {
    llSetText(message,color,1.0);
}

// Stato di inizializzazione.
default {
    state_entry() {
        configNotecard = llGetScriptName()+".config";
        showOutput("Reading "+configNotecard,<0.0,1.0,0.0>);
        line = 0;
        requestId = llGetNotecardLine(configNotecard,line);
    }

    state_exit() {
        line = -1;
        requestId = NULL_KEY;
        showOutput("",ZERO_VECTOR);
    }

    dataserver(key request_id, string data) {
        if(requestId==request_id) {
            if(data!=EOF) {
                data = llStringTrim(data,STRING_TRIM);
                if(llSubStringIndex(data,"#")!=0&&llStringLength(data)>0) {
                    list dataList = llParseString2List(data,["="],[]);
                    string var = llToUpper(llStringTrim(llList2String(dataList,0),STRING_TRIM));
                    string val = "";
                    if(llGetListLength(dataList)==2) val = llStringTrim(llList2String(dataList,1),STRING_TRIM);
                    readConfig(var,val);
                }
                line++;
                requestId = llGetNotecardLine(configNotecard,line);
            }
            else {
                integer validate = validateConfig();
                if(validate == TRUE) state ConfigOkState;
                else state ConfigErrorState;
            }
        }
    }
}

// Stato se la configurazione è andata a buon fine.
state ConfigOkState {
    state_entry() {
        // SE TUTTO E' ANDATO BENE VISUALIZZO IL TESTO SULL'OGGETTO CON I PARAMETRI DEL FILE DI CONFIGURAZIONE
        llSetText(text,color,1.0);
    }

    changed(integer change) {
        if(change & CHANGED_INVENTORY) llResetScript();
    }
}

// Stato se la configurazione è errata.
state ConfigErrorState {
    state_entry() {
        // SE TUTTO E' ANDATO MALE VISUALIZZO UN ERRORE
        llOwnerSay("Errore di configurazione nel file "+configNotecard);
    }
    changed(integer change) {
        if(change & CHANGED_INVENTORY) llResetScript();
    }
}

Buono Scripting LSL a tutti!

Categorie:Lezioni LSL Tag:

Video di Natale per CBM Italia Onlus

19 dicembre 2008 2 commenti

Video di Natale girato alla Land del Forum per CBM Italia Onlus dal grande Yash!

Io sono quello al minuto 2:57!

Categorie:Second Life, Video Tag: ,

Indecisione.

8 settembre 2008 36 commenti

Indeciso fino alla fine se rispondere o tacere. Molti mi consiglierebbero di tacere, sopratutto i miei nemici. Ma il punto è capire chi sono questi nemici… perché il non lo so.

Allora li esamino ad uno ad uno… a partire dalla più importante Alice.

Ovviamente non sei la più importante, ma ti piace pensare di esserlo (il grassetto ovviamente non sei tu, ma adoro il tuo egocentrismo che ti fa accaparrare tutto l’accaparrabile). Ma si, sei una mia amica. Perchè con te c’è sempre stato un rapporto di odio e odio, ma di quello che mi ha sempre portato a dire “Io Alice devo conoscerla di persona”, ed ho molti testimoni che possono confermare questa mia frase. Abbiamo avuto tantissimi battibecchi in passato e ne avremo almeno altri duemila in futuro, sei testarda da morire, ma anche se è molto duro farlo, con te si può parlare.

E con te ho finito! Quindi non cercare altri riferimenti alla tua persona dopo questa riga perché sono finiti, volendo puoi anche chiudere la pagina.

Tornando seri…

Sumichan non so chi sia, ma le sue parole, come quelle di Castalia, sono sempre state le lette con un grande sorriso. Penso sia positivo!

Helm è un amico anche in RL. Continuo a non capire i suoi riferimenti alla cricca di intoccabili, che continua ad essere una sterile polemica. Helm, è cosi che la penso e credo di averla detta in tutte le salse. Tra gli intoccabili, o presunti tali, vi sono (parlando di ex-mod) MarcoDuff, Annett, Alice, Enea e tra gli utenti Publio, Esecutore, Darko? Tutti questi hanno ricevuto almeno un richiamo nella loro carriera e più di uno un ban. i continuo a domandare… chi sono questi privilegiati? Se X fa 1 a Y ed Y, per risposta, fa 100 a X… mi dispiace, è Y che avrà le conseguenze peggiori. Si, è brutto a dirsi… ma mica sei autorizzato a sparare in testa ad un ladro che ti ruba casa, no? In ogni caso, continuo a dire… lasciate correrre… chi se ne frega! Provate a chiarire tra di voi… è Second Life! Spetta a noi residenti renderla migliore della nostra First Life!

Sonia. Questa è stata una sorpresa… visto che non mi aspettavo quel tipo di post. Faccio subito una premessa sulla parte iniziale, non so perché l’hai scritta, probabilmente per errore ma sinceramente non l’ho capita. Io non ho apportato alcuna censura al commento. Nessun commento viene censurato, esiste una moderazione per il semplice fatto che essendo il mio blog voglio che scrivano al suo interno soltanto persone che conosco, il filtro sta sull’autore, assolutamente non sul contenuto. Sonia, non mi sono mai vantato di essere un lupo, figuriamoci! E’ stata una etichetta che mi è stata associata e alla quale sono rimasto molto affezionato. No, non sono un animale nobile e nemmeno una faina, non mi interessa il pettegolezzo e non sono mai stato il primo ad attaccare. Le mie sono sempre state delle risposte ragionate, magari in ritardo, ma mai fatte con cattiveria. Conosco mille persone disposte a dimostrare esattamente il contrario di quello che ho affermato e ne conosco altrettante mille capaci di confermarlo… lascio a questi duecento individui la briga di giudicarmi, cosa che ovviamente non faranno perché sono tre o quattro di quelli non mi ignorano come è giusto che sia!

Angelica *umpf*. Altra persona che vorrei conoscere per capire se sei vera oppure ti diverti ad impersonare un personaggio. Inizio chiedendoti scusa. Ti chiedo scusa perché probabilmente mi sono espresso male nel mio post. Il tuo commento, infatti, devo ignorarlo… perché rispondi a frasi non rivolte a te in modo nemmeno esatto. Penso che tutto sia da ricondurre alla mancata comprensione del post. Tanto per fare degli esempi: la citazione “E’ una guerra e bisogna combattere” che fai è ovviamente una frase ironica, non esiste nessuna guarra! Implica il fatto che non ti ho mai visto come una nemica, al massimo come una ingenua, come tu stessa confermi di essere in più di un pm che mi hai inviato in passato. Inoltre ho parlato del ban a te e basta! Dove ho affermato che non andavano presi altri provvedimenti verso altre persone? Dove ho detto che non parli mai per te stessa? Penso che lo fai! Inoltre non ho nessun preconcetto nei tuoi confronti… la tua voglia di polemizzare contro la moderazione è risaputa come da tua stessa affermazione (PM), ma capisco anche che lo fai per difendere “a modo tuo” la community (che IMHO è il modo peggiore per difenderla). Ultima precisazione… non ho nessun problema a dire che la bannata è Angelica Lean, ma scherziamo??? Anche questo era un riferimento ad una frase urlata sui bannati che mi ha fatto ridere! E poi c’è veramente qualcuno che non ha capito che eri tu???

Sul legittimo disprezzo avrei da ridire… perché non ho capito. O meglio, il disprezzo alla fine ci può stare, pazienza, avrò sbagliato qualche cosa… il legittimo può essere discutibile. Ma quello su cui non si discute è ovviamente il regolamento. Capisco che un navigatore con un quoziente intellettivo pari a 1 ci stia meno di un micro secondo a scoprire la mia professione, ma che un amministratore di un forum, che è andato via da un altro forum per questo stesso motivo, nel suo forum si vanti ricevendo anche complimenti da altri utenti di aver fatto un regolamento che tuteli la sfera personale degli iscritti, e che poi si permetta di scrivere la mia professione violando le stesse regole scritte da lui, mi lascia quantomeno perplesso. Ma tranquilla, faccio io il primo passo. Voglio collaborare! Autorizzo ufficialmente l’amministratore a scrivere la mia professione sul suo forum! Perché è di questo che parlavo… collaborare e mi dispiace aver ricevuto una chiusura da parte tua. Dicevo che avere alternative sarebbe bello e stimolante. Chi se ne frega di chi ha più utenti! Tutti sappiamo che il numero del forum è falsato… e allora? Chi ha detto che sono migliori le community con 1000 iscritti postanti rispetto ad una con 1000000 iscritti con 100 postanti? Penso che community sia un luogo dove ti senti a tuo agio. Io nel mio forum sto a mio agio. Nel tuo ovviamente no, tanto che non sono iscritto. Ma non lo prendere come un attacco! Parliamoci chiaro, su 276 post quanti parlano di Second Life (visto che più della metà stanno in aree private)? Per una volta ascoltate il consiglio del vostro moderatore Darko, basta parlare del forum (sul serio… il tuo sembra il Forum del Forum!)! Inizia a mettere contenuti e togli quella stupida regola “vietato insultare la moderatrice da siti esterni”!!! Ma daiiiii!!! E poi chiamavi la mia censura??? Metti un paio di contenuti in quel forum, pulisci il db e stai certa che al primo topic interessante sugli script avrai un nuovo utente iscritto (perchè é cosi che mi farai sentire a mio agio e attirerai utenti attivi… altrimenti attiri utenti con rancore odio o come lo chiami tu, legittimo disprezzo!).

Piccola precisazione per non perdere amicizie! Non ho mai identificato come nemico Tayra e Sonia… con Tayra continuiamo a sentirci in modo più o meno regolare per piacevoli brevi chiacchierate su script. Magari abbiamo avuto discussioni in passato (anche se adesso non le focalizzo), ma penso si siano risolte nel migliore dei modi! Darko è un caso a parte anche se non lo reputo un nemico. Sfortunatamente con lui non riesco a spiegarmi in modo corretto, sopratutto utilizzando mezzi come PM chat e compagnia bella. Per questo motivo ho dato a Darko il mio numero di cellulare, cosa che non avrei sicuramente dato ad un nemico o ad una persona con cui voglio chiudere un rapporto. Inoltre lui mi ha pure regalato la sua collezione 2007 in SL! Detto questo… mi sono rimasti veramente pochi nemici… appena ho i nomi li posto!

Dulcis in fundo… un rapporto va curato… ma che significa curare? Perché alcune volte ho come l’impressione che serva un manuale, un insieme di regole da seguire, in modo preciso, senza mai sbagliare altrimeti cadi! Caschi giù e di nuovo tutto da capo… ma sempre più fragile.

Categorie:Second Life Tag:

Ieri. Oggi. Domani.

5 settembre 2008 7 commenti

Seconda vita del cavolo.

Il che equivale a dire vita del cavolo. Ma per fortuna solo una parte, una piccolissima parte, la parte più piccola in assoluto.

Perché ho la grande fortuna che le persone importanti della seconda vita adesso fanno parte della prima vita.

Perché ho la grande sfortuna che le persone importanti della seconda vita adesso fanno parte della prima vita.

Non mi sono creato una seconda vità per scappare dalla mia prima bellissima vita, ma come la mettiamo se io adesso volessi scappare dalla mia second vita. No, non sono l’unico che l’ha fatto… una persona, finita nel dimenticatoio ormai da tanto tempo, dimeticata dai più, l’ha fatto. Si chiama Iao… o forse si chiamava, visto che non so nemmeno che fine abbia fatto… ogni tanto domando. Ed un’altra persona a cui sono molto affezionato sta lasciando lentamente… lentamente perché so che in cuore suo non vuole farlo, ma ne è costretta dalla noia e dalla polemica… Medea.

E a queste chi si aggiunge? Io? Forse si, forse no. Sarebbe bello avere alternative, fare parte di più community, condividere le informazioni, collaborare, evitare polemica. Ma, guardate la coincidenza della frase, questo nelle community straniere accade in Italia no! Si, il riferimento è dritto a te. Perché come te, ogni giorno ti leggo e sorrido… sorrido per ipocrisia. Fino a quando sei ipocrita con il nemico, ci può stare! E’ una guerra e bisogna combattere… ma non puoi essere ipocrita con le tue stesse frasi o peggio ancora con la tua stessa firma. Ma ti capisco, l’odio ed il rancore rende ciechi.

E poi un’altra… la bannata della situazione. Adesso prendi appunti, perché grazie alla mia non indifferenza ho avuto un grosso battibecco con la moderazione ed ho litigato in modo aspro con una cara amica. Quindi non ti azzardare un’altra volta a dire che gli ex-moderatori sono privilegiati, che ci sono utenti tutelati e che si fa sempre una barriera per difendere i moderatori. Hai avuto la dimostrazione in mano che Annett non è stata privilegiata, che se esistono utenti privilegiati quella sei stata proprio tu visto che personalmente ti avrei bannato già una settimana fa e per molti più giorni e che le barricate non esistono visto che personalmente ho litigato e discusso con buona parte della moderazione in modo incivile ma rispettando il regolamento, ecco perché non ti accorgi di nulla visto che questo tipo di comunicazioni vanno fatte via PM. Quindi la prossima volta che ti vengono queste idee pensa bene a quello che vedi scritto qui, perché se continui, IMHO, sei solo una ragazzina amante della polemica.

E se qualcuno scrive una frase per solidarietà, per un saluto, per divertimento e la mette in firma ci stiamo (me compreso) un micro secondo a scandirla e a vederci dietrologie sataniche o riti voodoo. Facciamoci un favore, rilassiamoci, me compreso.

Dulcis in fundo tu. Si ho sbagliato. Si abbiamo sbagliato. Si ogni tanto si fa. Si, dovevo prima contattarti e mandarti a quel paese come esordio, come fai di solito tu. Non l’ho fatto, amicizia finita? Se la mia amicizia con te è legata ad un filo cosi sottile, che basta un pollaio a distruggerlo, per una volta sono io a dire che non ho perso nulla. E continuerò a chiamarlo cosi, pollaio, perchè se una gallina solo per il gusto di usare il suo becco dice che le da fastidio il grassetto le cose sono due, o civilmente vi innalzate dal ruolo di galline scambiandovi insulti costruttivi via pm, o almeno ti innalzi solo tu dal livello gallina e per un breve periodo di tempo eviti il grassetto per diplomazia… penché scrivere proprio quel nome in grassetto è un chiaro, chiarissimo segnale diretto… non lo ha fatto di proposito, siamo noi a vederci il lato oscuro ed abbiamo sbagliato tutti a darti contro senza chiedere spiegazioni… per questo personalmente ti chiedo scusa… ma rifletti anche sotto altri punti di vista.

Per una volta, forse il lupo è stanco… si vuole riposare. Perché quando si combatte con la stupidità lo si fa con il sorriso e divertendosi un mondo… ma quando arrivi a combattere pure con gli amici è finita.

Categorie:Second Life Tag:

Nuove Funzioni LSL

29 agosto 2008 Nessun commento

Sono state implementate 8 nuove funzioni lsl (disponibili con dal client 1.21).

Vediamo di esaminarle una per una.

Sei di queste sono di tipo llDetected* applicabili esclusivamente in un contesto di tipo Touch e che accettano in ingresso il solito indice che tiene conto dei click multipli.

integer llDetectedTouchFace(integer index);
Restituisce il numero della faccia toccata.

vector llDetectedTouchPos(integer index);
Posizione del punto toccato in coordinate globali (regione).

vector llDetectedTouchST(integer index);
Posizione del punto toccato nella faccia in percentuale.

vector llDetectedTouchUV(integer index);
Posizione del punto toccato nella faccia in coordinate UV.

vector llDetectedTouchNormal(integer index);
Vettore normale alla superficie nel punto toccato.

vector llDetectedTouchBinormal(integer index);
Vettore tangente alla superficie nel punto toccato.

Una funzione riguarda le informazioni su un agent.

string llGetAgentLanguage(key agentKey);
Restituisce il codice della lingua dell’agent rappresentato dalla key.

Una funzione riguarda la regione.

integer llGetRegionAgentCount();
Restituisce il numero degli agent nella regione in cui gira lo script.

Se volete provarle tutte quante con un click, ecco un codice di esempio:

default {
    touch_start(integer total_number) {
        integer i;
        for(i=0;i<total_number;i++) {
            key agentKey = llDetectedKey(i);
            string agentName = llDetectedName(i);
            string agentLanguage = llGetAgentLanguage(agentKey);
            
            llOwnerSay("*** Informazioni Agent ***");
            llOwnerSay("Nome: "+agentName);
            llOwnerSay("Key: "+(string)agentKey);
            llOwnerSay("Lingua: "+agentLanguage);

            integer faceIndex = llDetectedTouchFace(i);
            vector posVec = llDetectedTouchPos(i);
            vector posSTVec = llDetectedTouchST(i);
            vector posUVVec = llDetectedTouchUV(i);
            vector normalVec = llDetectedTouchNormal(i);
            vector tangentVec = llDetectedTouchBinormal(i);
            
            llOwnerSay("*** Informazioni Tocco ***");
            llOwnerSay("Faccia: "+(string)faceIndex);
            llOwnerSay("Posizione toccata (Regione): "+(string)posVec);
            llOwnerSay("Posizione toccata (ST): "+(string)posSTVec);
            llOwnerSay("Posizione toccata (UV): "+(string)posUVVec);
            llOwnerSay("Vettore normale: "+(string)normalVec);
            llOwnerSay("Vettore tangente: "+(string)tangentVec);
            
            
        }            
        integer agentInRegion = llGetRegionAgentCount();
            
        llOwnerSay("*** Informazioni Region ***");
        llOwnerSay("Numero agent: "+(string)agentInRegion);
    }
}
Categorie:Second Life Tag: